CREATE OR REPLACE PACKAGE x
AS
   TYPE t IS TABLE OF NUMBER
      INDEX BY PLS_INTEGER;

   FUNCTION f
      RETURN t;
END x;

CREATE OR REPLACE FUNCTION index_type (type_owner      VARCHAR2, 
                                       type_name       VARCHAR2, 
                                       type_subname    VARCHAR2) 
   RETURN VARCHAR2 
IS 
   l_result   VARCHAR2 (50) := 'UNKNOWN'; 
BEGIN 
   EXECUTE IMMEDIATE 
         q'[ 
      DECLARE 
        l_result VARCHAR(50); 
        v "]' 
      || type_owner 
      || '"."' 
      || type_name 
      || '"."' 
      || type_subname 
      || q'["; 
      BEGIN 
        BEGIN 
          v('A') := NULL; 
          l_result := 'VARCHAR2'; 
        EXCEPTION 
          WHEN OTHERS THEN 
            BEGIN 
              v(1) := NULL; 
              l_result := 'PLS_INTEGER'; 
            EXCEPTION 
              WHEN OTHERS THEN l_result := 'UNKNOWN'; 
            END; 
        END; 
 
        :result := l_result; 
      END;]' 
      USING OUT l_result; 
 
   RETURN l_result; 
EXCEPTION 
   WHEN OTHERS 
   THEN 
      RETURN SQLERRM; 
END index_type;

SELECT type_owner, 
       type_name, 
       type_subname, 
       index_type (type_owner, type_name, type_subname) AS index_type 
  FROM user_arguments 
 WHERE data_type = 'PL/SQL TABLE'