CREATE TABLE employees
AS
   SELECT * FROM hr.employees

CREATE OR REPLACE PACKAGE my_arrays
IS
   TYPE employees_t IS TABLE OF employees%ROWTYPE
      INDEX BY PLS_INTEGER;
END;

If You Can Do It in SQL....

DECLARE 
   l_employees   my_arrays.employees_t; 
BEGIN 
   DBMS_OUTPUT.PUT_LINE ('*********** Sort by Last Name'); 
 
   /* Fill the collection from the table to  
      get things started. But just to be clear: 
      the more common use case for this ordering 
      will be with data what was pushed into the 
      collection from a PL/SQL-based algorithm - 
      not in any order or not easily sorted in your 
      code. */ 
 
   SELECT * 
     BULK COLLECT INTO l_employees 
     FROM employees; 
 
   FOR emp IN (  SELECT * 
                   FROM TABLE (l_employees) 
                  WHERE department_id = 80 
               ORDER BY last_name) 
   LOOP 
      DBMS_OUTPUT.put_line ( 
         emp.department_id || '-' || emp.last_name); 
   END LOOP; 
 
   DBMS_OUTPUT.PUT_LINE ('*********** Sort by Hire Date'); 
 
   FOR emp IN (  SELECT * 
                   FROM TABLE (l_employees) 
                  WHERE last_name LIKE '%e%' 
               ORDER BY hire_date DESC) 
   LOOP 
      DBMS_OUTPUT.put_line ( 
         TO_CHAR (emp.hire_date) || '-' || emp.last_name); 
   END LOOP; 
END;

Replace Contents of Collection with New Order

DECLARE 
   l_employees   my_arrays.employees_t; 
   l_employees2   my_arrays.employees_t; 
BEGIN 
   DBMS_OUTPUT.PUT_LINE ('Sort by Last Name'); 
 
   /* Fill the collection from the table to  
      get things started. */ 
 
   SELECT * 
     BULK COLLECT INTO l_employees 
     FROM employees; 
 
   /* Re-order the contents of the collection  
      using SQL */ 
 
   SELECT * 
     BULK COLLECT INTO l_employees2 
     FROM TABLE (l_employees) 
    ORDER BY last_name; 
 
   /* Iterate through collection by index value 
      to verify new order. */ 
 
   FOR indx IN 1 .. l_employees2.COUNT 
   LOOP 
      DBMS_OUTPUT.put_line (l_employees2(indx).last_name); 
   END LOOP; 
END;