create or replace function tab_grp(sum_cols  DBMS_TF.COLUMNS_T, t DBMS_TF.Table_t, grp_cols  DBMS_TF.COLUMNS_T)   
  return varchar2 SQL_Macro  as 
v_sum_list varchar2(4000); 
v_grp_list varchar2(4000); 
begin 
  -- concat the SUM column 
 FOR i IN 1 .. sum_cols.count() LOOP 
      v_sum_list := v_sum_list || case when i > 1 then ',' end || 'SUM('|| sum_cols(i)|| ') '|| sum_cols(i); 
  END LOOP; 
  FOR i IN 1 .. grp_cols.count() LOOP 
      v_grp_list := v_grp_list || case when i > 1 then ',' end || grp_cols(i); 
  END LOOP; 
  return 'select '  || v_grp_list || ', ' || v_sum_list ||' , count(*) cnt from t group by '|| v_grp_list ; 
end; 

create table tab as 
select 1 customer_id, 1 product_id, 10 value from dual union all 
select 1 customer_id, 1 product_id, 40 value from dual union all 
select 1 customer_id, 2 product_id, 20 value from dual union all 
select 2 customer_id, 1 product_id, 10 value from dual union all 
select 2 customer_id, 1 product_id, 20 value from dual

 select * from tab_grp (columns(value), tab, columns(customer_id, product_id))

DECLARE 
  l_clob CLOB; 
BEGIN 
  DBMS_UTILITY.expand_sql_text ( 
    input_sql_text  => q'[select * from tab_grp (columns(value), tab, columns(customer_id, product_id))]', 
    output_sql_text => l_clob  ); 
  DBMS_OUTPUT.put_line(l_clob); 
END;