Resource Requiring Cleanup

CREATE OR REPLACE PACKAGE serial_package AUTHID DEFINER  
AS  
   CURSOR emps_cur  
   IS  
      SELECT *  
        FROM employees;  
END serial_package; 

Use Cleanup Subprogram Where Needed

CREATE OR REPLACE PROCEDURE use_packaged_cursor AUTHID DEFINER  
IS  
   PROCEDURE cleanup  
   IS  
   BEGIN  
      /* If called from exception section log the error */  
      IF SQLCODE <> 0  
      THEN  
         /* Consider using open source Logger utility:  
               https://github.com/OraOpenSource/Logger   
         logger.log_error ('use_packaged_cursor');  
         */ 
         DBMS_OUTPUT.PUT_LINE ('Error!'); 
      END IF;  
        
      IF serial_package.emps_cur%ISOPEN  
      THEN  
         CLOSE serial_package.emps_cur;  
      END IF;  
   END cleanup;  
BEGIN  
   OPEN serial_package.emps_cur;  
     
   cleanup;  
EXCEPTION  
   WHEN NO_DATA_FOUND  
   THEN  
      /* Clean up but do not re-raise (just to show that you might want  
         different behaviors for different exceptions). */  
      cleanup;  
        
   WHEN OTHERS  
   THEN  
      cleanup;  
      RAISE;  
END; 

BEGIN 
   use_packaged_cursor; 
END; 

BEGIN  
   use_packaged_cursor;  
END;