SQLCODE Outside of Exception Section Always 0

BEGIN 
   DBMS_OUTPUT.put_line (SQLCODE); 
END;

SQLCODE Invoked via Nested Subprogram from Exception Section

DECLARE 
   PROCEDURE my_proc 
   IS 
   BEGIN 
      DBMS_OUTPUT.put_line ( 
            'Nested subprogram called from exception section SQLCODE=' 
         || SQLCODE); 
   END; 
BEGIN 
   RAISE NO_DATA_FOUND; 
EXCEPTION 
   WHEN OTHERS 
   THEN 
      my_proc; 
END; 

Watch the Changing SQLCODE Value

DECLARE 
   aname   VARCHAR2 (5); 
BEGIN 
   BEGIN 
      aname := 'Big String'; 
      DBMS_OUTPUT.put_line (aname); 
   EXCEPTION 
      WHEN VALUE_ERROR 
      THEN 
         DBMS_OUTPUT.put_line ( 
             'Inner block exception section SQLCODE='||SQLCODE); 
   END; 
 
   DBMS_OUTPUT.put_line ('In executable section SQLCODE='||SQLCODE); 
EXCEPTION 
   WHEN VALUE_ERROR 
   THEN 
      DBMS_OUTPUT.put_line ( 
          'Outer block exception section SQLCODE='||SQLCODE); 
END;

ALTER SESSION SET plsql_warnings = 'enable:all' 

CREATE OR REPLACE PROCEDURE swallow_error AUTHID DEFINER 
IS  
   aname   VARCHAR2 (5);  
BEGIN  
   BEGIN  
      aname := 'Big';  
      DBMS_OUTPUT.put_line (aname);  
   EXCEPTION  
      WHEN OTHERS  
      THEN  
         DBMS_OUTPUT.put_line (  
             'Inner block exception section SQLCODE='||SQLCODE);  
   END;  
  
   DBMS_OUTPUT.put_line ('In executable section SQLCODE='||SQLCODE);  
EXCEPTION  
   WHEN VALUE_ERROR  
   THEN  
      DBMS_OUTPUT.put_line (  
          'Outer block exception section SQLCODE='||SQLCODE);  
END; 

SELECT text FROM USER_ERRORS 
 WHERE name = 'SWALLOW_ERROR'