Create the PTF implementation package rand_col_p.

CREATE PACKAGE rand_col_p AS 
 
  FUNCTION describe(tab       IN OUT DBMS_TF.table_t,  
                    col_count        NATURALN DEFAULT 1,   
                    low              NUMBER   DEFAULT NULL,  
                    high             NUMBER   DEFAULT NULL)  
           RETURN DBMS_TF.describe_t; 
 
  PROCEDURE fetch_rows(col_count NATURALN DEFAULT 1,   
                       low       NUMBER   DEFAULT NULL,  
                       high      NUMBER   DEFAULT NULL); 
  
 
END rand_col_p;  

Create the PTF implementation package body rand_col_p.

CREATE PACKAGE BODY rand_col_p AS 
  col_name_prefix CONSTANT dbms_id := 'RAND_'; 
 
  FUNCTION describe(tab       IN OUT DBMS_TF.table_t,  
                    col_count        NATURALN DEFAULT 1,   
                    low              NUMBER   DEFAULT NULL,  
                    high             NUMBER   DEFAULT NULL)  
           RETURN DBMS_TF.describe_t 
  AS  
    cols DBMS_TF.columns_new_t; 
  BEGIN  
    FOR i IN 1 .. col_count LOOP 
     cols(i):= DBMS_TF.column_metadata_t(name=>col_name_prefix||i, TYPE=>DBMS_TF.type_number); 
    END LOOP; 
 
    RETURN DBMS_TF.describe_t(new_columns => cols); 
  END; 
 
  PROCEDURE fetch_rows(col_count NATURALN DEFAULT 1,   
                       low       NUMBER   DEFAULT NULL,  
                       high      NUMBER   DEFAULT NULL)  
  AS 
    row_count CONSTANT PLS_INTEGER := DBMS_TF.get_env().row_count; 
    col       DBMS_TF.tab_number_t; 
  BEGIN 
    FOR c IN 1 .. col_count LOOP 
      FOR i IN 1 .. row_count LOOP 
        col(i) :=  CASE WHEN (low IS NULL OR high IS NULL) 
                        THEN dbms_random.VALUE  
	                ELSE dbms_random.VALUE(low, high)  
	           END; 
      END LOOP; 
      DBMS_TF.put_col(c, col); 
    END LOOP; 
  END; 
 
END rand_col_p;  

Create the standalone rand_col PTF.

CREATE FUNCTION rand_col(tab TABLE,  
                  col_count NATURALN DEFAULT 1,   
                  low       NUMBER   DEFAULT NULL,  
                  high      NUMBER   DEFAULT NULL) 
                RETURN TABLE  
                PIPELINED ROW POLYMORPHIC USING rand_col_p; 

SELECT *  FROM rand_col(scott.dept)

SELECT *  
FROM rand_col(scott.dept, col_count => 2)

SELECT ename, job, rand_1, rand_2, rand_3 
FROM   rand_col(scott.emp, col_count => 3, low => -10, high => +10) 
WHERE  job != 'SALESMAN'